@ECHO OFF

REM Version: V01
REM Date:  20181108

REM ============== USAGE ==============
REM flashall_AFT.cmd [Format option] [SN number]
REM  [Format option]: 1=enable, 0=disable. default=0
REM        Format userdata/cache
REM  [SN number]:  device SN number
REM        Support multiple download image

REM ============== setting ==============

CLS
SET "dataerase=0"
SET "SSN="
SET "para="
SET "ERASEPARM="
SET "RESETPARM=0"

set flash_raw=.\zc600kl_flash_raw.exe
set fastboot=.\fastboot.exe

IF %1 EQU 1 ( SET ERASEPARM=-f )
IF %1 EQU 1 ( SET RESETPARM=1 )
IF %1 EQU 0 ( SET ERASEPARM= )
IF NOT [%2] EQU [] ( SET para=-s )
IF NOT [%2] EQU [] (
    SET SSN=%2
)

%fastboot% getvar version-bootloader %para% %SSN% 2>&1 | find /c "ZC600KL-12345678"
if %errorlevel% equ 1 goto ASUS_P_ABL
echo "flash upgrade_abl_630.elf…"
%fastboot% flash %para% %SSN% abl upgrade_abl_630.elf
%fastboot% reboot-bootloader %para% %SSN%
@ping 127.0.0.1 -n 5 -w 1000 > nul

:ASUS_P_ABL
call:flash

rem pause
EXIT 0
rem goto END

REM ============== flash() ==============
:flash

ECHO "%flash_raw% %para% %SSN% AFT %ERASEPARM% "
%flash_raw% %para% %SSN% AFT %ERASEPARM%
echo errorlevel="%ERRORLEVEL%"
IF "%ERRORLEVEL%" == "0" (
 IF EXIST .\.ImageE\ ( RD /S /Q .\.ImageE\ )
 ECHO "Success: %flash_raw% %para% %SSN% AFT %ERASEPARM% , EXIT!"
 IF %RESETPARM% == 1 (
 %fastboot% %para% %SSN% oem reset-dev_info
 %fastboot% %para% %SSN% oem force-reset
 )
 %fastboot% %para% %SSN% oem adb_enable
 echo update Images done.
 goto :END
)
ECHO "FAILED: %flash_raw% %para% %SSN% AFT %ERASEPARM% failure, EXIT!"
goto :Error

:Error
echo Image Update ERROR !!!
goto :END

:END