@echo off
@rem  *****************************************************************
@rem  Script to deploy a WIMboot WIM on a target device in a standard configuration
@rem  *****************************************************************
@rem Initialize WinPE
@echo wpeinit
wpeinit
@echo.
@echo.
@echo.
@echo *****************************************************************
@rem  Get the USB Drive letter of the device we booted WinPE from
@echo *****************************************************************
@echo call wpeutil UpdateBootInfo
wpeutil UpdateBootInfo
@echo.
set WinPEREG="HKLM\System\CurrentControlSet\Control"
set WinPEKey=PEBootRamdiskSourceDrive
@echo.
@rem Get volume letter of USB Key
@echo for /f "skip=2 tokens=3" %%A in ('call Reg query %WinPEREG% /v %WinPEKEY%') do set WinPESource=%%A
for /f "skip=2 tokens=3" %%A in ('call Reg query %WinPEREG% /v %WinPEKEY%') do set WinPESource=%%A
@echo WinPESource is drive letter "%WinPESource%"
@echo.
@echo.
@echo.
@echo *****************************************************************
@echo  Setting up the partition table
@echo *****************************************************************
@echo call diskpart /s %WinPESource%DiskpartFiles\wimpart.txt
diskpart /s %WinPESource%DiskpartFiles\wimpart.txt
@echo.
@echo.
@echo.
@echo *****************************************************************
@rem  Map drive letter for Install.wim and Winre.wim
@echo *****************************************************************
@rem Create an output file containing all the drive letters
@echo call diskpart /s %WinPESource%DiskpartFiles\listVol.txt>%WinPESource%Output.txt
diskpart /s %WinPESource%DiskpartFiles\listVol.txt>%WinPESource%Output.txt
@echo.
@rem Go through each drive letter, looking for the images\Install.txt file
for /f "skip=8 tokens=3" %%A in (%WinPESource%Output.txt) do (
if exist %%A:\images\install.txt set InstallPath=%%A:\images&& "echo Found device with images folder and install.txt file"
)
@echo.
@echo.
@rem Check InstallPath was found and there are images in it.
if NOT EXIST %InstallPath%\Install.wim echo "Install.wim NOT found." && goto :Error
@echo Install.wim FOUND at %InstallPath%\images\install.wim
@echo.
@rem Check that Winre.wim is there as well.
if NOT EXIST %InstallPath%\Winre.wim echo "Winre.wim NOT found." && goto :Error
@echo Winre.wim FOUND at %InstallPath%\images\winre.wim
@echo.
@echo.
@echo.
@echo *****************************************************************
@rem  Switches to the USB disk
@rem  Create folders on local (eMMC) disk and copy files from USB disk
@echo *****************************************************************
@echo.
@echo Making directories…
md c:\recycler\scratch
if %errorlevel% NEQ 0 echo "Failed to make c:\recycler\scratch directory" && goto :error
md m:\"windows images"
if %errorlevel% NEQ 0 echo "Failed to make m:\windows images directory" && goto :error
md m:\recovery\windowsre
if %errorlevel% NEQ 0 echo "Failed to make m:\recovery\windowsre directory" && goto :error
@echo.
@echo copy %InstallPath%\install.wim m:\"windows images"
copy %InstallPath%\install.wim m:\"windows images"
if %errorlevel% NEQ 0 echo "Failed to copy install.wim to m:\Windows images" && goto :error
@echo.
@echo copy %InstallPath%\winre.wim m:\recovery\windowsre
copy %InstallPath%\winre.wim m:\recovery\windowsre
if %errorlevel% NEQ 0 echo "Failed to copy winre.wim to m:\recovery\windowsre" && goto :error
@echo.
@echo.
@echo.
@echo *****************************************************************
@echo Applying the WIMboot image from the Images Partition in the eMMC
@echo  USB disk NO LONGER NEEDED from this point
@echo *****************************************************************
@echo call DISM /Apply-Image /ImageFile:"m:\windows images\install.wim" /ApplyDir:c: /Index:1 /WIMBoot /ScratchDir:c:\recycler\SCRATCH
DISM /Apply-Image /ImageFile:"m:\windows images\install.wim" /ApplyDir:c: /Index:1 /WIMBoot /ScratchDir:c:\recycler\SCRATCH
if %errorlevel% NEQ 0 echo "Failed to apply image to c:" && goto :error
@echo.
@echo.
@echo.
@echo *****************************************************************
@echo  Setting the boot environment
@echo *****************************************************************
@echo call c:\WINDOWS\SYSTEM32\BCDBOOT c:\WINDOWS /s s: /f all
c:\WINDOWS\SYSTEM32\BCDBOOT c:\WINDOWS /s s: /f all
if %errorlevel% NEQ 0 echo "Failed to set boot information" && goto :error
@echo.
@echo.
@echo.
@echo *****************************************************************
@echo  Setting the recovery environment
@echo *****************************************************************
@echo c:\windows\system32\reagentc /SetREImage /Path M:\RECOVERY\WINDOWSRE /target c:\windows
c:\windows\system32\reagentc /SetREImage /Path M:\RECOVERY\WINDOWSRE /target c:\windows
if %errorlevel% NEQ 0 echo "Failed to set recovery information" && goto :error
@echo.
@echo.
@echo.
@echo *****************************************************************
@echo  WIMboot image deployment COMPLETE. Type EXIT from Command
@echo  Prompt to restart or turn off device.
@echo *****************************************************************
goto :END

:ERROR
@echo.
@echo An error has been detected.
@echo.

:END