@echo off

REM fbflash.bat
REM Batch file to flash all partitions to target using fastboot
REM Usage is fbflash <variant-name>
REM Typical scenario
REM 1. Download zip file from autobuild
REM 2. unzip zip file
REM 3. cd to top level directory in zip file
REM 4. On target, boot to U-Boot, connect USB cable
REM    run "fastboot"
REM 4. On host, run "fbflash.bat <name-of-variant>"
REM

if "%1" equ "" (
  echo Usage: fbflash.bat "variant"
  echo        where variant is "IslandLMP", "Island" etc
  exit /b 1
)

set variant=%1
set MY_DIR=.

for /F "delims=[]= tokens=2,3,4"  %%i in ( %MY_DIR%\variants\%variant% ) do (
  set itype=%%i
  set filename_unix=%%j
  set ram_addr=%%k
  call :cmd_process
)
set MY_DIR=
exit /b 0

@rem this must be outside the 'for' loop, to do the substring operation or the string substitution.
:cmd_process
  set filename_win=%filename_unix:/=\%
  if %itype:~0,8% equ preflash (
    echo SKIP preflash image %filename_win%
  ) else (
    if %itype% equ oem (
REM   First, do fastboot getvar serialno
REM   This works around the "fastboot flakiness" problem on Windows PCs
      fastboot getvar serialno
      if ERRORLEVEL 1 (
        set MY_DIR=
        echo Error: fastboot getvar serialno failed
        exit /b 1
      )
      echo oem %filename_win%
      fastboot.exe oem %filename_win% 2>&1
    ) else (
      fastboot.exe flash %itype% %variant%\%filename_win% 2>&1
    )
    if ERRORLEVEL 1 (
      set MY_DIR=
      echo Error: fastboot %itype% %filename_win% failed
      exit /b 1
    )
  )
  set MY_DIR=
  exit /b 0