@echo off
@rem  This script is called by x:\Windows\System32\Startnet.cmd – WinPE
@echo.
@echo.
@echo.
@echo Running Intel Optimization powercfg for improved imaging times
@echo.
@echo.
@rem  *****************************************************************
@rem  List all the disks, then search the volumes of each one to see
@rem  which disks may have "Winpe" in the label. We will ignore that
@rem  disk and use the first disk without the Winpe label that we find.
@rem  *****************************************************************
echo.
echo Find disk
echo.
REM SSD(Type: RAID)
for /l %%i in (0,1,3) do (
    echo select disk %%i > x:\detdisk.txt
    echo detail disk >> x:\detdisk.txt
    diskpart /s x:\detdisk.txt > x:\det.txt
    find /i "Type   : RAID" x:\det.txt
    if not errorlevel 1 set Disk=%%i
)
if defined Disk goto :FORMAT

REM SSD(Type: PCIE)
for /l %%i in (0,1,3) do (
    echo select disk %%i > x:\detdisk.txt
    echo detail disk >> x:\detdisk.txt
    diskpart /s x:\detdisk.txt > x:\det.txt
    find /i "Type   : Nvme" x:\det.txt
    if not errorlevel 1 set Disk=%%i
)
if defined Disk goto :FORMAT

REM SSD/HDD(Type: SATA)
for /l %%i in (0,1,3) do (
    echo select disk %%i > x:\detdisk.txt
    echo detail disk >> x:\detdisk.txt
    diskpart /s x:\detdisk.txt > x:\det.txt
    find /i "Type   : SATA" x:\det.txt
    if not errorlevel 1 set Disk=%%i
)
if defined Disk goto :FORMAT

REM eMMC
for /l %%i in (0,1,3) do (
    echo select disk %%i > x:\detdisk.txt
    echo detail disk >> x:\detdisk.txt
    diskpart /s x:\detdisk.txt > x:\det.txt
    find /i "Type   : SD" x:\det.txt
    if not errorlevel 1 set Disk=%%i
)
if not defined Disk echo Cannot find disk. && goto :ERROR

:FORMAT
echo.
echo Using disk %Disk%
@echo.
@echo.
@echo.
@rem  *****************************************************************
@rem    Detect if System is booted into UEFI mode or Bios mode
@rem  *****************************************************************
for /f "tokens=2* delims= " %%A in ('reg query HKLM\System\CurrentControlSet\Control /v PEFirmwareType') do set Firmware=%%B
@echo.
if %Firmware%==0×1 goto :Biosmode
if %Firmware%==0×2 goto :UEFImode
Goto :END
:UEFImode
@echo.
@rem ************************
@rem UEFI SECTION
@rem ************************
@echo The PC is booted in UEFI mode
@echo.>x:\winpart.txt
@echo select disk "%Disk%">>x:\winpart.txt
@echo clean>>x:\winpart.txt
@echo convert gpt>>x:\winpart.txt
@echo create partition efi size=100>>x:\winpart.txt
@echo format quick fs=fat32 label="System">>x:\winpart.txt
@echo assign letter="S">>x:\winpart.txt
@echo create partition msr size=16>>x:\winpart.txt
@echo create partition primary>>x:\winpart.txt
@echo format quick fs=ntfs label="Local Disk">>x:\winpart.txt
@echo assign letter="W">>x:\winpart.txt
@echo shrink desired=1000>>x:\winpart.txt
@echo create partition primary>>x:\winpart.txt
@echo format quick fs=ntfs label="Recovery">>x:\winpart.txt
@echo assign letter="R">>x:\winpart.txt
@echo set id="de94bba4-06d1-4d40-a16a-bfd50179d6ac">>x:\winpart.txt
@echo gpt attributes=0×8000000000000001>>x:\winpart.txt
@echo exit>>x:\WinPart.txt
Goto :WINPARTSECTION

:Biosmode
@rem ************************
@rem BIOS SECTION
@rem ************************
@echo The PC is booted in BIOS mode
@echo The PC is booted in BIOS mode>x:\Bios.txt
@echo.>x:\winpart.txt
@echo select disk "%Disk%">>x:\winpart.txt
@echo clean>>x:\winpart.txt
@echo create partition primary size=100>>x:\winpart.txt
@echo active>>x:\winpart.txt
@echo format quick fs=fat32 label="System">>x:\winpart.txt
@echo assign letter="S">>x:\winpart.txt
@echo create partition primary>>x:\winpart.txt
@echo format quick fs=ntfs label="Windows">>x:\winpart.txt
@echo assign letter="W">>x:\winpart.txt
@echo exit>>x:\winpart.txt
@echo.

:WINPARTSECTION
@echo Winpart.txt now contains…..
@echo.
type x:\winpart.txt
@echo.
@echo.
@echo *****************************************************************
@echo  Setting up the partition table
@echo *****************************************************************
@echo call diskpart /s x:\winpart.txt
diskpart /s x:\winpart.txt
@echo.
@echo.
@echo *****************************************************************
@rem  Map drive letter for Install.wim
@echo *****************************************************************
@echo.>x:\ListVol.txt
@echo List volume>>x:\ListVol.txt
@echo exit>>x:\ListVol.txt
@echo call diskpart /s x:\ListVol.txt
call diskpart /s x:\ListVol.txt>x:\Output.txt
@echo.
@echo.
@rem Go through each drive letter, looking for the images\Install.txt file
for /f "skip=8 tokens=3" %%A in (x:\Output.txt) do (
if exist %%A:\images\install.txt set InstallPath=%%A:\images&& echo "Found device with images folder and install.txt file"
)
@echo.
@echo.
@rem Check InstallPath was found and there are images in it.
if NOT EXIST %InstallPath%\Install.wim echo "Install.wim NOT found." && goto :Error
@echo Install.wim FOUND at %InstallPath%\images\install.wim
@echo.
@echo.
@echo Making directories…
md w:\recycler\scratch
if %errorlevel% NEQ 0 echo "Failed to make w:\recycler\scratch directory" && goto :error
@echo.
md r:\recovery\windowsre
if %errorlevel% NEQ 0 echo "Failed to make m:\recovery\windowsre directory" && goto :error
@echo.
@echo *****************************************************************
@echo  Applying the Windows image from the USB
@echo *****************************************************************
@echo call DISM /Apply-Image /ImageFile:%InstallPath%\install.wim /Index:1  /ApplyDir:w:\ /Compact /ScratchDir:w:\recycler\SCRATCH
call DISM /Apply-Image /ImageFile:%InstallPath%\install.wim /Index:1 /ApplyDir:w:\ /Compact /ScratchDir:w:\recycler\SCRATCH
if %errorlevel% NEQ 0 echo "Failed to apply image to w:" && goto :error
@echo.
@echo.
Reg load HKLM\temp W:\Windows\system32\config\software
for /f "tokens=7 delims=\" %%A In ('reg query "HKLM\temp\Microsoft\windows NT\CurrentVersion\profilelist"') do set id=%%A
for /f "tokens=3 delims=\" %%B In ('reg query "HKLM\temp\Microsoft\windows NT\CurrentVersion\profilelist\%id%" /v ProfileImagePath') do set user=%%B
reg delete "HKLM\temp\Microsoft\windows NT\CurrentVersion\profilelist\%id%" /f
Reg unload HKLM\temp
rd /s /q "w:\users\%user%"
@echo.
@echo.
@echo.
@echo.
@echo *****************************************************************
@rem  Move WinRE to Recovery Partition
@echo *****************************************************************
@echo.
@echo Modifying attributes of winre.wim so we can move it.
attrib w:\Windows\System32\recovery\winre.wim -s -h -a -r
@echo move w:\Windows\System32\recovery\winre.wim r:\recovery\windowsre
move w:\Windows\System32\recovery\winre.wim r:\recovery\windowsre
if %errorlevel% NEQ 0 echo "Failed to move winre.wim to r:\recovery\windowsre" && goto :error
@echo.
@echo reset attributes now
attrib r:\Recovery\Windowsre\winre.wim +s +h +a +r
@echo.
@echo.
@echo *****************************************************************
@echo  Setting the boot environment
@echo *****************************************************************
@echo call w:\WINDOWS\SYSTEM32\BCDBOOT w:\WINDOWS /s s: /f all
w:\WINDOWS\SYSTEM32\BCDBOOT w:\WINDOWS /s s: /f all
if %errorlevel% NEQ 0 echo "Failed to set boot information" && goto :error
@echo.
@echo.
@echo.
@echo *****************************************************************
@echo  Setting the recovery environment
@echo *****************************************************************
@echo w:\windows\system32\reagentc /SetREImage /Path r:\RECOVERY\WINDOWSRE /target w:\windows
w:\windows\system32\reagentc /SetREImage /Path r:\RECOVERY\WINDOWSRE /target w:\windows
if %errorlevel% NEQ 0 echo "Failed to set recovery information" && goto :error
@echo.
mkdir S:\EFI\OEM
xcopy /e /h /y S:\EFI\Microsoft\* S:\EFI\OEM\
del /a S:\EFI\OEM\Boot\BCD
bcdedit /createstore S:\BCD
bcdedit /store S:\BCD /create {bootmgr} /d "Windows Boot Manager"
bcdedit /store S:\BCD /set {bootmgr} device partition=S:
bcdedit /store S:\BCD /set {bootmgr} locale en-us
bcdedit /store S:\BCD /set {bootmgr} integrityservices Enable

bcdedit /store S:\BCD /create {11111111-1111-1111-1111-111111111111} /d "Windows Recovery" /device
bcdedit /store S:\BCD /set {11111111-1111-1111-1111-111111111111} ramdisksdidevice partition=R:
bcdedit /store S:\BCD /set {11111111-1111-1111-1111-111111111111} ramdisksdipath \Recovery\WindowsRE\boot.sdi

bcdedit /store S:\BCD /create {22222222-2222-2222-2222-222222222222} /d "Windows Recovery Environment" /application osloader
bcdedit /store S:\BCD /set {bootmgr} default {22222222-2222-2222-2222-222222222222}
bcdedit /store S:\BCD /set {bootmgr} displayorder {22222222-2222-2222-2222-222222222222}

bcdedit /store S:\BCD /set {default} device ramdisk=[R:]\Recovery\WindowsRE\winre.wim,{11111111-1111-1111-1111-111111111111}
bcdedit /store S:\BCD /set {default} path \Windows\System32\winload.efi
bcdedit /store S:\BCD /set {default} locale en-us
bcdedit /store S:\BCD /set {default} displaymessage "Recovery"
bcdedit /store S:\BCD /set {default} osdevice ramdisk=[R:]\Recovery\WindowsRE\winre.wim,{11111111-1111-1111-1111-111111111111}
bcdedit /store S:\BCD /set {default} systemroot \Windows
bcdedit /store S:\BCD /set {default} nx OptIn
bcdedit /store S:\BCD /set {default} bootmenupolicy Standard
bcdedit /store S:\BCD /set {default} winpe Yes

xcopy /h /y S:\BCD* S:\EFI\OEM\Boot\.
del /a S:\BCD*
@echo.
@echo.
@echo *****************************************************************
@echo  Copying over Unattend.xml to use on factory floor if it exists
@echo *****************************************************************
@echo if EXIST %WinPESource%Scripts\Unattend.xml copy %WinPESource%Scripts\Unattend.xml w:\Windows\Panther /y
if EXIST %WinPESource%Scripts\Unattend.xml copy %WinPESource%Scripts\Unattend.xml w:\Windows\Panther /y
@echo.
@echo *****************************************************************
@echo  Copying over NON Scanstate Packages, if they exist.
@echo  IF YOU COPY OVER SCANSTATE PPKG, THIS CAUSE IMAGE TO FAIL DURING RECOVERY
@echo *****************************************************************
@echo if EXIST %WinPESource%Scripts\*.ppkg copy %WinPESource%Scripts\*.ppkg r:\Recovery\Customizations /y
if EXIST %WinPESource%Scripts\*.ppkg copy %WinPESource%Scripts\*.ppkg r:\Recovery\Customizations /y
@echo.
@echo *****************************************************************
@echo  Copying over resetconfig.xml and assets, if they exist.
@echo *****************************************************************
@echo if EXIST %WinPESource%Scripts\Recovery\OEM\resetconfig.xml xcopy %WinPESource%Scripts\Recovery\*.* w:\Recovery /e /y
if EXIST %WinPESource%Scripts\Recovery\OEM\resetconfig.xml xcopy %WinPESource%Scripts\Recovery\*.* w:\Recovery /e /y
@echo.
@echo.
@echo *****************************************************************
@echo  Copying over oobe.xml.
@echo *****************************************************************
@echo xcopy %WinPESource%Scripts\Recovery\OEM\Scripts\oobexml\Oobe\*.* w:\Windows\System32\oobe\ /e /y
xcopy %WinPESource%Scripts\Recovery\OEM\Scripts\oobexml\Oobe\*.* w:\Windows\System32\oobe\ /e /y
@echo.
xcopy %WinPESource%Scripts\Recovery\OEM\Scripts\csup.txt w:\Windows\ /y
xcopy %WinPESource%Scripts\Recovery\OEM\Scripts\OSversion\*.* w:\Windows\ /y
xcopy %WinPESource%Scripts\Recovery\OEM\Scripts\logo2.bmp w:\Windows\System32\ /y
@echo.
@echo.
@echo.
@echo *****************************************************************
@echo.
@echo.
@echo *****************************************************************
@echo  Image deployment COMPLETE. Type EXIT from Command
@echo  Prompt to restart or turn off device.
@echo *****************************************************************
goto :END

:ERROR
@echo.
@echo An error has been detected.
@echo.
goto :END

:ListPar
@REM This section is to bring a disk number and use it to List Partitions
@echo.
set TempDisk=%1
diskpart /s x:\Par.txt>x:\ParOutput.txt
for /f "skip=26 tokens=4" %%A in (x:\ParOutput.txt) do (
if /i NOT "%%A"=="Winpe" set Disk=%TempDisk%
)
Goto :EOF

:END
@rem
@rem  Get finish time so we can evaluate total WinPE phase time.
@rem
call |time>x:\StopTime.txt
@rem
@rem  Now parse both files to display the Start and Finish Time
@rem
@echo.
@echo.
for /f "tokens=5" %%A in (x:\starttime.txt) do echo Script Start Time is %%A
for /f "tokens=5" %%A in (x:\stoptime.txt) do echo  Script Stop Time is %%A
@echo.